새로운 글
새로운 덧글

파이어몽키로 안드로이드 앱 개발 시 장치에 접근하는 기능(예, 카메라 이용, 블루투스 이용 등) 개발 시 권한 설정이 필요합니다.

 

기존에는 Project > Options > Uses Permissions에서 필요한 권한을 설정하는 방식이었지만, 

안드로이드 API 최신버전은 런타임 시 권한을 요청하는 매커니즘으로 변경되었습니다.

 

기존의 권한 모델은 설치 시 전체 권한을 승인하는 방식이었습니다. 새로운 권한 모델은 기능 사용 시 개별 권한을 묻는 방식으로, 사용자는 기능 별 허용 및 거부가 가능해졌습니다.

기존 권한 요청 방식 새로운 권한 요청 방식

새로운 권한 요청 방식은 RAD 스튜디오 10.3 부터 적용되며, 

기존에 작성했던 안드로이드 프로젝트는 권한 요청하는 로직을 추가하도록 업데이트 해야 합니다.

 

안드로이드의 권한 요청 로직

안드로이드 권한 요청은 System.Permissions.pas에 구현된 PermissionsService.RequestPermissions 메소드를 호출하는 것으로 시작합니다.

 

다음 코드는 델파이 샘플 중 Location(Object Pascal/Mobile Snippets/Location)의 일부입니다.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
procedure TLocationForm.swLocationSensorActiveSwitch(Sender: TObject);
begin
{$IFDEF ANDROID}
  if swLocationSensorActive.IsChecked then
    PermissionsService.RequestPermissions([JStringToString(TJManifest_permission.JavaClass.ACCESS_FINE_LOCATION)],
      procedure(const APermissions: TArray<string>; const AGrantResults: TArray<TPermissionStatus>)
      begin
        if (Length(AGrantResults) = 1) and (AGrantResults[0] = TPermissionStatus.Granted) then
          { activate or deactivate the location sensor }
          LocationSensor1.Active := True
        else
        begin
          swLocationSensorActive.IsChecked := False;
          TDialogService.ShowMessage('Location permission not granted');
        end;
      end)
  else
{$ENDIF}
    LocationSensor1.Active := False;
end;

위코드에서는 TLocationsSensor 즉, GPS 연동하는 코드 전에 안드로이드인 경우({$IFDEF ANDROD}) 위치 권한(TJManifest_permission.JavaClass.ACCESS_FINE_LOCATION)을 요청하는 코드가 추가되었습니다.

 

RequestPermissions 메소드의 파라메터는 다음과 같습니다.

1
2
3
procedure RequestPermissions(const APermissions: TArray<string>;
  const AOnRequestPermissionsResult: TRequestPermissionsResultEvent;
  AOnDisplayRationale: TDisplayRationaleEvent = nil); overload; virtual;

첫번째 파라메터는 요청하는 권한 문자열 배열, 두번째는 권한 요청 결과를 받아볼 수 있는 메소드, 세번째는 사용자에게 권한에 대한 안내를 할 수 있는 메소드입니다.

 

델파이 샘플의 AccessCameraApp의 코드에는 권한요청하는 로직이 다음과 같이 구현되어 있습니다.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
procedure TAccessCameraAppForm.btnTakePhotoClick(Sender: TObject);
begin
  PermissionsService.RequestPermissions(
    [FPermissionCamera, FPermissionReadExternalStorage, FPermissionWriteExternalStorage],
    TakePicturePermissionRequestResult,
    DisplayRationale
  )
end;
 
// Optional rationale display routine to display permission requirement rationale to the user
procedure TAccessCameraAppForm.DisplayRationale(Sender: TObject; const APermissions: TArray<string>; const APostRationaleProc: TProc);
var
  I: Integer;
  RationaleMsg: string;
begin
  for I := 0 to High(APermissions) do
  begin
    if APermissions[I] = FPermissionCamera then
      RationaleMsg := RationaleMsg + 'The app needs to access the camera to take a photo' + SLineBreak + SLineBreak
    else if APermissions[I] = FPermissionReadExternalStorage then
      RationaleMsg := RationaleMsg + 'The app needs to read a photo file from your device';
  end;
 
  // Show an explanation to the user *asynchronously* - don't block this thread waiting for the user's response!
  // After the user sees the explanation, invoke the post-rationale routine to request the permissions
  TDialogService.ShowMessage(RationaleMsg,
    procedure(const AResult: TModalResult)
    begin
      APostRationaleProc;
    end)
end;
 
procedure TAccessCameraAppForm.TakePicturePermissionRequestResult(Sender: TObject; const APermissions: TArray<string>; const AGrantResults: TArray<TPermissionStatus>);
begin
  // 3 permissions involved: CAMERA, READ_EXTERNAL_STORAGE and WRITE_EXTERNAL_STORAGE
  if (Length(AGrantResults) = 3)
      and (AGrantResults[0] = TPermissionStatus.Granted)
      and (AGrantResults[1] = TPermissionStatus.Granted)
      and (AGrantResults[2] = TPermissionStatus.Granted) then
    TakePhotoFromCameraAction1.Execute
  else
    TDialogService.ShowMessage('Cannot take a photo because the required permissions are not all granted')
end;

1) 3가지 권한을 요청합니다.

2) DisplayRationale 메소드에서 필요한 권한에 대해 설명합니다.

3) 요청결과 메소드에서 권한일 모두 허용한 경우 기능을 실행합니다.

 

위에서 주의할 점은, 

권한에 대한 설명 시(DisplayRationale 메소드) 메시지 호출 후 비동기로 APostRationaleProc 메소드를 호출해야 합니다.

그리고, 권한에 대한 설명 메소드는 옵션으로 생략할 수 있습니다.

 

위 내용을 참고해 권한이 필요한 기능을 개발하는 경우 해당 기능 호출 전 권한을 요청하도록 추가 및 기존 코드를 변경하시기 바랍니다.

해당 기능은 안드로이드 앱 개발 시 적용해야 하는 기능으로, 다른 플랫폼 앱 개발 시 생략할 수 있습니다.

 

엠바카데로에서 제공하는 내용과 이미 적용된 샘플 앱의 목록은 다음 링크에서 확인할 수 있습니다.

 

다음 글들이 안드로이드 권한 모델 적용 내용이 업데이트 되었습니다.

번호 제목 글쓴이 날짜 조회 수
공지 [10.3 리오][업데이트 3] What's NEW! 신기능 자세히 보기 관리자 2019.11.22 1758
공지 RAD스튜디오(델파이,C++빌더) - 고객 사례 목록 관리자 2018.10.23 3965
공지 [데브기어 컨설팅] 모바일 앱 & 업그레이드 마이그레이션 [1] 관리자 2017.02.06 6784
공지 [전체 목록] 이 달의 기술자료 & 기술레터 관리자 2017.02.06 3197
공지 [프로그래밍 강의] 2019.8~2019.12 관리자 2015.01.22 10222
공지 RAD스튜디오(델파이, C++빌더) - 시작하기 관리자 2015.06.30 16376
공지 RAD스튜디오(델파이,C++빌더) - 모바일 앱 개발 사례 (2019년 11월 업데이트 됨) 험프리 2014.01.16 153717
1078 윈도우와 맥 개발 시작을 위한 파이어몽키 코스북: 무료 다운로드 제공(385페이지) 관리자 2013.04.05 152099
1077 델파이 튜토리얼 자습서 이용 안내 관리자 2014.09.01 71175
1076 이 달의 기술자료 - 2014년 11월 험프리 2014.10.13 53906
1075 CD-ROM 열고 닫기 박병일 2011.12.22 44581
1074 최신버전에서 ComPort(시리얼 통신) 컴포넌트 설치안내 [10] file 험프리 2013.12.04 37416
1073 이 달의 기술자료 - 2014년 12월 file 험프리 2014.11.26 32249
1072 이 달의 기술자료 - 2014년 6월 file 험프리 2014.06.05 30111
1071 RAD Studio XE6 Update1 발표 [1] Humphery 2014.06.20 29253
1070 [Android] 폰번호 가져오기 [1] 타락천사 2014.09.05 23009
1069 델파이 XE2에서 dbExpress를 이용해 오라클 연결하기 file 박병일 2012.02.15 17355
1068 SendMessage 함수를 이용한 메세지 전송 관리자 2012.01.05 17037
1067 이 달의 기술자료 - 2014년 4월 file 험프리 2014.04.03 16311
1066 이 달의 기술자료 - 2015년 03월 험프리 2015.02.25 15651
1065 다중 클라이언트를 위한 DataSnap 서버 만들기 관리자 2011.12.22 15431
1064 델파이 XE2 로 아이폰 하드웨어 컨트롤 하기 박병일 2012.01.19 15281
1063 이 달의 기술자료 - 2015년 02월 file 험프리 2015.01.29 14833
1062 델파이XE2의 VCL Styles 활용하기 박병일 2012.01.19 14669
1061 델파이XE2 파이어몽키 기반 아이폰앱 개발에서 제스춰를 인식시키는 방법 박병일 2012.01.25 14012


광고 모듈이 설치되어 있지 않아 실행을 중단합니다..