RAD 서버는 REST 기반 멀티티어 아키텍처를 구현할 수 있는 통합 미들웨어 서버입니다.

RAD 서버를 이용해 REST 기반 서비스 애플리케이션을 신속하게 구축하고 배포할 수 있습니다. - 자세히보기

 

RAD 서버는 REST 엔드포인트 제공, 통합 미들웨어, 응용 프로그램 서비스 등 다양한 기능을 제공하지만, 핵심 기능은 다양한 데이터를 JSON 포맷으로 입출력 처리하는 REST 엔드포인트 제공 기능입니다.

이 글에서는 RDBMS 데이터를 JSON 포맷으로 손쉽게 제공하는 TEMSDataSetResource 컴포넌트와 실무 활용방안을 설명합니다.

 

이 글에서 다음 내용을 설명합니다.

1) 데이터셋 JSON 처리 자동화하기 - TEMSDataSetResource 컴포넌트 소개

2) 자동화에 비지니스 로직 추가하기 - 엔드포인트 메소드 이용

3) 목록과 상세를 다른 항목으로 제공하도록 처리하는 방법

 

REST 아키텍처가 생소하거나, RAD 서버가 익숙하지 않다면, 하단 추가정보의 REST API 소개 및 구현방안을 먼저 살펴보길 권장합니다.

 

데이터셋 JSON 처리 자동화하기

TEMSDataSetResource 컴포넌트(이하 데이터셋 리소스)는 데이터셋(DB 테이블)에 대한 JSON 처리 작업을 자동화 하는 컴포넌트입니다.(RAD 스튜디오 10.3 버전부터 지원)

TEMSDataSetResource 컴포넌트의 주요 특징은 다음과 같습니다.

  • 데이터셋 JSON 처리 자동화
  • 허용 액션(AllowAction: List, Get, Post, Put, Delete) 지정
  • 목록 요청 시 페이징 처리(PageParamName, PageSize) 및 정렬 지정(SoringParamPrefix)
  • 제공할 항목 지정(ValueFields)

먼저, 데이터셋 JSON 처리 자동화 기능은 지정된 데이터셋(TFDQuery 등)의 데이터를 JSON으로 제공(List, Get)하고, 요청한 JSON 데이터를 데이터셋에 적용(Post, Put, Delete)하는 작업을 컴포넌트 단에서 처리합니다.

 

기존에는 엔드포인트 메소드를 직접 구현 해 위 작업을 진행했습니다.

 

기존의 엔드포인트 메소드 구현 방식과 비교해봅니다.

 

기존 엔드포인트 메소드 방식은 다음과 같이 구현합니다.

Get 엔드포인트 메소드를 비교하면, Get 엔드포인트 메소드를 추가하고, 데이터베이스의 내용을 조회 후 JSON 포맷의 데이터를 직접 만들어 반환합니다.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
type
  [ResourceName('books')]
  TBookResource1 = class(TDataModule)
    FDConnection1: TFDConnection;
    qryBook: TFDQuery;
  published
    procedure Get(const AContext: TEndpointContext; const ARequest: TEndpointRequest; const AResponse: TEndpointResponse);
  end;
 
procedure TBookResource1.Get(const AContext: TEndpointContext; const ARequest: TEndpointRequest; const AResponse: TEndpointResponse);
var
  writer: TJsonTextWriter;
begin
  writer := AResponse.Body.JSONWriter;
   
  Writer.WriteStartObject;
  Writer.WritePropertyName('books');
 
  Writer.WriteStartObject;
  Writer.WritePropertyName('total');
  Writer.WriteValue(qryBook.RecordCount);
 
  Writer.WritePropertyName('book');
  Writer.WriteStartArray;
   
  qryBook.Open;
  while not qryBook.Eof do
  begin
    Writer.WriteStartObject;
    Writer.WritePropertyName('BOOK_SEQ');
    Writer.WriteValue(qryBook.FieldByName('BOOK_SEQ').AsInteger);
 
    // JSON 필드 설정 생략
 
    Writer.WriteEndObject;
    qryBook.Next;
  end;
   
  Writer.WriteEndArray;
 
  Writer.WriteEndObject;
  Writer.WriteEndObject;
     
  AResponse.Body.SetValue(Writer.JSON as TJSONValue, True);
end;

 

데이터셋 리소스를 이용하는 방식은 다음과 같습니다.

TEMDDataSetResource 컴포넌트 추가 후, DataSet을 연결 및 제공할 행위인 AllowAction을 지정, 선언부에 ResourceSuffix 특성(Attribute) 추가. 끝~

1
2
3
4
5
6
7
8
type
  [ResourceName('books')]
  TBookRentalResource1 = class(TDataModule)
    FDConnection1: TFDConnection;
    qryBook: TFDQuery;
    [ResourceSuffix('list', '/')]
    EMSDataSetResource1: TEMSDataSetResource;
  end;

위 두가지 방식의 결과가 동일하지는 않지만 목적은 동일합니다. 데이터베이스의 내용을 질의해 그 결과를 JSON으로 제공합니다.

위 예제는 목록 데이터에 대한 것만 구현했습니다. 입력(Post), 추가(Put), 삭제(Delete) 등의 기능을 구현하면 구현해야할 코드의 차이는 어마어마 합니다.

 

즉, 데이터셋 리소스를 사용하면 테이블의 CRUD 작업을 매우 간단하고 쉽게 구현할 수 있습니다.

또한, 페이징과 정렬 등의 부가 기능도 속성 설정만으로 사용 가능합니다.

 

 

페이징

PageParamName과 PageSize 속성을 지정하면, 다음과 같은 요청으로 페이징 처리 가능합니다.

  • http://localhost:8080/books?page={페이지 번호}

정렬

SortingParamPrefix 지정 후 다음과 같이 요청 시 정렬된 데이터를 제공합니다.

  • http://localhost:8080/books?sf{정렬할 필드명}={A 또는 D}
    • sf : SortingParamPrefix에 설정된 값
    • {정렬할 필드명} : 정렬할 대상 테이블의 필드이름
    • {A 또는 D} : 정렬방식, A(Ascending: 오름차순), D(Descending: 내림차순)
  • 예> http://localhost:8080/books?sfBook_Title=A

 

결론, 데이터셋 리소스를 사용하면 기존 엔드포인트 메소드 사용시보다 코드의 양을 대폭 줄일 수 있습니다.

 

다음으로는 제가 직접 사용하며 필요한 기능들을 추가 구현한 내용을 보강합니다.

 

자동화 비지니스 로직 추가하기

데이터셋 리소스는 엔드포인트 요청 시 데이터 처리 작업을 자동으로 진행해 편리합니다.

하지만 일부 데이터의 경우 데이터를 변환하거나, 유효성 검증 등의 비지니스 로직을 데이터 처리 이전에 구현할 필요가 있습니다.

 

처리 작업 전 비지니스 로직을 추가하기 위해서는, 기존의 엔드포인트 메소드와 데이터셋 리소스를 함께 사용해야 합니다.

 

기본 원리는 엔드포인트 메소드에서 비지니스 로직 처리 후 데이터셋 리소스의 엔드포인트 메소드를 호출하는 방식입니다.

 

다음 예제는 수정 요청 시 유효성 체크 후 데이터 처리하는 코드입니다.

엔드포인트 메소드(Put=PutItem=수정)를 통해 비지니스 로직을 구현합니다.

데이터셋 리소스의 엔드포인트 메소드를 호출 합니다. 매개변수를 그대로 전달합니다.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
procedure TTestResource1.PutItem(const AContext: TEndpointContext;
  const ARequest: TEndpointRequest; const AResponse: TEndpointResponse);
var
  Json: TJSONValue;
  Title: string;
begin
  JSON := ARequest.Body.GetValue;
  Title :=JSON.GetValue<string>('BOOK_TITLE');
 
  if Title = '' then
    AResponse.RaiseBadRequest;
 
  EMSDataSetResource1.Put(AContext, ARequest, AResponse);
end;

 

 

데이터셋 리소스의 엔드포인트 메소드는 다음과 같습니다.

  • List - 목록 요청
  • Get - 상세 요청
  • Post - 신규 생성
  • Put - 항목 수정
  • Delete - 항목 삭제

목록과 상세를 다른 항목으로 제공하기

데이터 요청은 목록을 요청하거나 상세를 요청할 수 있습니다. 도서정보를 예로 들면 목록은 "/books" 상세는 "/books/3" 등으로 요청합니다.

 

응답은 일반적으로 JSON 포맷으로 제공하며, 이때 목록과 상세의 항목을 동일하게 제공할 수도, 다르게 제공할 수도 있습니다.

데이터셋 리소스를 사용한다면 목록과 상세의 항목은 동일하게 제공됩니다.

 

하지만, 상세의 항목이 많거나, 데이터가 큰 경우 목록으로 제공 시 데이터가 너무 커질 수 있습니다. 그래서 목록은 주요 항목만 제공하고 상세 요청 시 모든 항목을 제공해야 할 필요가 있습니다.

 

이 요구사항 처리도 앞에서 살펴본 비지니스 로직 추가로 처리 가능합니다.

 

다음은 예제는 목록과 상세 항목을 다르게 제공하도록 비지니스 로직을 추가한 코드입니다.

목록과 상세 엔드포인트 메소드는 Get과 GetItem 입니다.

SQL 문장을 설정하는 코드를 추가해 원하는 기능을 구현할 수 있었습니다.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
procedure TBookRentalResource.Get(const AContext: TEndpointContext;
  const ARequest: TEndpointRequest; const AResponse: TEndpointResponse);
const
  SQL_LIST ='SELECT BOOK_SEQ, BOOK_TITLE, BOOK_AUTHOR, BOOK_PRICE FROM BOOK';
begin
  FDQuery1.SQL.Text := SQL_LIST;
  EMSDataSetResource1.List(AContext, ARequest, AResponse);
end;
 
procedure TBookRentalResource.GetItem(const AContext: TEndpointContext;
  const ARequest: TEndpointRequest; const AResponse: TEndpointResponse);
const
  SQL_ITEM_INFO = 'SELECT ' +
                    'BOOK_SEQ, BOOK_TITLE, BOOK_ISBN, BOOK_AUTHOR, BOOK_PRICE, ' +
                    'BOOK_LINK, BOOK_DESCRIPTION ' +
                  'FROM BOOK WHERE BOOK_SEQ = :BOOK_SEQ';
var
  Item: string;
begin
  Item := ARequest.Params.Values['id'];
  FDQuery1.SQL.Text := SQL_ITEM_INFO;
  FDQuery1.ParamByName('BOOK_SEQ').AsString := Item;
  EMSDataSetResource1.Get(AContext, ARequest, AResponse);
end;

RAD 서버로 REST API 개발은 상당히 간편합니다. 패키지로 결과물이 나오기 때문에 배포하기도 편리합니다. 그리고 데이터셋 리소스와 같은 기능을 이용하면 훨씬 더 쉽고 강력하게 개발할 수 있습니다.

직접 구현하다보면 필요한 기능이 있을 것입니다. 앞에서 설명한 비지니스로직 추가하는 방법을 활용해 대부분의 필요 기능을 구현 할수 있을 것입니다.

 

추가 정보

번호 제목 글쓴이 날짜 조회 수
공지 [DelphiCon 요약] 코드사이트 로깅 실전 활용 기법 (Real-world CodeSite Logging Techniques) 관리자 2021.01.19 14387
공지 [UX Summit 요약] 오른쪽 클릭은 옳다 (Right Click is Right) 관리자 2020.11.16 13023
공지 [10.4 시드니] What's NEW! 신기능 자세히 보기 관리자 2020.05.27 15532
공지 RAD스튜디오(델파이,C++빌더) - 고객 사례 목록 관리자 2018.10.23 21064
공지 [데브기어 컨설팅] 모바일 앱 & 업그레이드 마이그레이션 [1] 관리자 2017.02.06 22297
공지 [전체 목록] 이 달의 기술자료 & 기술레터 관리자 2017.02.06 17932
공지 RAD스튜디오(델파이, C++빌더) - 시작하기 [1] 관리자 2015.06.30 38228
공지 RAD스튜디오(델파이,C++빌더) - 모바일 앱 개발 사례 (2020년 11월 업데이트 됨) 험프리 2014.01.16 173741
463 [고객 사례- 의료, 델파이] COVID-19 격리 대상자 상태 관리 앱 관리자 2020.04.28 643
462 [기술백서] 다양한 팀 '협업' 방법론과 개발 방식 관리자 2020.03.18 643
461 [시애틀] 개발 효율성을 극대화할 수 있도록 멀티-모니터를 활용해 개발환경 레이아웃을 구축할 수 있습니다. Humphery 2015.09.04 643
460 이 달의 기술자료 - 2015년 08월 험프리 2015.07.28 642
459 [10.3 리오][업데이트 3] 엔터프라이즈 커넥터가 무상 제공됩니다 (엔터프라이즈, 아키텍트 사용 고객 한정) file 관리자 2019.11.22 642
458 이 달의 기술자료 - 2017년 12월 file 험프리 2017.11.24 642
457 [도서/PDF] 한 번에 개발하는 안드로이드&iOS 앱 with 델파이 2편 - 7장. 카메라(뷰 포인트)의 이해와 활용 관리자 2020.02.06 640
456 [업데이트][핫픽스][10,2 도쿄] 툴체인 이슈 핫픽스 험프리 2017.05.10 638
455 [고객 사례- 의료, 델파이] 의료용 소프트웨어(폐활량&심전도 체크) - Advanced Spirometer and ECG 관리자 2019.10.25 637
454 [RAD Studio 10.4 패치1 ] C ++ 디버깅과 누락 파일 패치 – 패치를 설치하는 새로운 방법! file 김원경 2020.06.01 635
453 [고객 사례- POS, C++빌더] YG-POS - 소상공인을 위한 무료 소프트웨어 관리자 2021.02.08 632
452 [10.2 도쿄] RTL file 김원경 2017.03.24 632
451 새롭게 출시될 RAD스튜디오 'NEW' 베타 버전, 지금 신청하세요! (유지보수계약 고객 한정) 관리자 2018.10.05 630
450 이 달의 기술자료 - 2016년 06월 file 험프리 2016.05.27 629
449 [10.2 도쿄][릴리즈3] 파이어몽키 UI 템플릿 관리자 2018.03.30 626
448 [10.2 도쿄][릴리즈2] RAD 서버 싱글 사이트 라이선스 제공 험프리 2017.12.13 626
447 코드 서명 – 여러분이 개발한 프로그램, 컴퓨터 바이러스처럼 보이지는 않나요? 관리자 2021.05.12 625
446 n [도서/PDF/소스코드] 시작하는 사람들을 위한 델파이 프로그래밍-모듈 13. 문자열과 숫자 타입을 서로 변환하기 관리자 2019.03.29 624
445 n [도서/PDF/소스코드] 시작하는 사람들을 위한 델파이 프로그래밍-모듈 8. 프로시저들 관리자 2019.03.29 624
444 [도서/PDF/소스코드] 델파이 Begin...End - 6장. 데이터베이스 프로그래밍 개요 관리자 2019.08.19 623