제너릭과 제너릭을 사용한 예제

제너릭이라는 단어는 자바등의 언어에서는 들어보거나 사용해 보신 분들도 있지만 델파이 개발자들은 아직 생소하거나 코드를 제대로 구현해 본적이 없는 분들도 있습니다. 또한 기존의 소스를 수정하시는 것이 번거롭다고 생각할수도 있습니다.

 

그래서 이 자료에서는 델파이 2009버전부터 추가되어 사용되는 제너릭의 전반적인 개념과 델파이에서 사용되는 제너릭 컬렉션 등을 소개해 보도록 하겠습니다.

 

제너릭이 무엇인지 설명하기 전에 델파이에서 제너릭을 사용하지 않았던 시점의 코드를 한 번 살펴 보도록 하겠습니다.

 

제너릭을 사용하지 않은 선언 및 호출

 

프로시저와 함수들을 선언할 때 우리는 항상 프로시저, 함수 등의 매개변수 타입을 미리 선언하고 사용하였습니다.

function Add(x,y:integer):integer;

 

function Divide(x,y:real):real;

 

function Test(x,y:string):string;

 

  특히 dll 같은 외부 프로세스의 루틴을 호출하기 위해 프로시저, 함수 변수들을 따로 선언합니다.

Type

 TAddFunc = function(x,y:integer):integer;

 TDivFunc = function(x,y:real):real;

 

Var

 AddFunc:TAddFunc;

 DivFunc:TDivFunc;

 

 TestFunc:function(x,y:string):string;  //타입 선언하지 않고 변수를 직접 선언 할 수도 있음

 

 

또는 클래스를 정의할 때 다음과 같이 선언 합니다.

TSIPare = class

    Private

      FKey :String;

      FValue :Integer;

    Public

      Function GetKey:String;

      Procedure Setkey(Key:string);

      Function GetValue:Integer;

      Procedure SetValue(Value:Integer);

      Property Key:string read GetKey write SetKey;

      Property Value:integer read GetValue write SetValue;

  end; 

 

만일 string,string 또는 integer, integer, integer,string 을 타입으로 갖는 클래스가 각각 필요하다면, 코드를 복사해서 

TSSPair, TIIPair. TISPare 클래스들은 선언하게 될 것입니다.

 

배열을 사용하고 데이터를 입력할 경우에도 다음과 같이 코드를 구현하곤 했었죠.

 

Type

TCountry = array[0..2] of String; //정적배열

 

Var

 Countires:Country =(‘한국’, ‘일본’, ‘미국’);

 TestLists:array of string;  //동적배열

 IA:array of integer;

 

implementation

Procedure TForm1.Button1Click(Sender:TObject);

Var

   I:byte;

Begin

   SetLength(TestLists,3);

   TestLists[0] := ‘a’;

 TestLists[1] := ‘b’;

 TestLists[2] := ‘c’;

 

 SetLength(IA,10);

 

 For i:= 0 to 9 do 

 Begin

    IA[i] := i;

 End;

End;

 

위의 예제에서 다른 타입의 데이터를 처리하는 배열이 필요하다면 여러분들은 다시 배열타입이나 변수를 선언하고

데이터를 처리 할 것 입니다. 그럼 이제 제너릭에 대해서 소개하도록 하겠습니다.

 

제너릭이란 ?

 

제너릭(Generic)이란, 데이터의 타입(data type)을 일반화한다(generalize)는 것을 의미합니다

 

클래스나 메소드를 정의할 때구체적인 타입(type)을 적지 않고 변수형태로 적어 놓는 것입니다클래스 생성이나 메소드 호출 시점에 지정하는 방식으로, 자료형에 대한 안정성을 높일 수 있습니다. 이때 클래스메소드에서의 자료형은 사용자가 스스로 선택할 수 있도록 범용적인 상태로 정하게 됩니다.

(참고: generic이라는 영어 단어는, 특정되지 않은 일반적인 이라는 뜻으로, generic product는, 나이키 같은 특정 상표가 붙지 않은 상품을뜻합니다)

 

앞에서 제너릭을 사용하지 않은 예제를 제너릭을 사용하여 수정해 보도록 하겠습니다.

 

 

제너릭을 사용한 메소드 호출 

 

Type

 

 TCalcFunc<T> = function(x,y:T):T;

 

Procedure TForm1.Button1Click(Sender:TObject);

Var

  CalcFunc:TCalcFunc<integer>;

 

Begin

CalcFunc := Add;

ShowMessage(IntToStr(CalcFunc(2,3));

end;

 

 

l  제너릭 클래스 예제

Type

  TPair<TKey,TValue> = class

      Private

         FKey :TKey;

         FValue :TValue;

      Public

         Function GetKey:TKey;

         Procedure Setkey(Key:TKey);

         Function GetValue:TValue;

         Procedure SetValue(Value:TValue);

         Property Key:TKey read GetKey write SetKey;

         Property Value:TValue read GetValue write SetValue;

  end;

 

   TSIPair  = TPair<String,Integer>;

   TSSPair = TPair<String,String>;

 TIIPair   =  TPair<Integer,Integer>;

  TISPair  = TPair<Integer,String>;

 

제너릭 클래스(Genenric Class)에서는 타입을 변수로 표시합니다이를 타입 매개변수(type parameter)”라고 하며

타입 매개변수는 개체 생성 시에 프로그래머에 의하여 결정 됩니다. 

 

 

l  제너릭 컬렉션 클래스

 

언어에 제너릭 타입()이 추가되면서 델파이에는 제너릭 컬렉션() 기본 세트가 추가되었습니다. 이 세트는 System.Generics.Collections 유닛에 있으며컨테이너에 담고 싶은 데이터 타입을 여러분이 직접 지정할 있도록, 제네릭한 (, 컨테이너에 담길 타입이 사전에 특정되지 않은) 컨테이너의 밑그림을 제공합니다. 제너릭 컬렉션()에는 다음과 같은 것들이 있습니다:

 

  • TList<T>: 기본 제너릭 리스트로 정렬과 열거(enumeration) 지원합니다.

     

  • TThreadList<T>: 쓰래드에 안전한 리스트로서 잠금(locking)을 지원합니다.

     

  • TQueue<T>, TStack<T>

     

  • TArray<T>

     

  • TDictionary<TKey,TValue>: 상당히 막강한 딕셔너리이며, (key)와 값(value)의 타입을 필요에 맞게 지정할 수 있습니다.

     

  • TObjectList<T: class>: 객체 타입을 담을 수 있으며 소유권을 지원합니다.(아래의 컨테이너들도 동일)

     

  • TObjectQueue<T: class>, TObjectStack<T: class>

     

  • TObjectDictionary<TKey,TValue>

     

  • TThreadedQueue<T>

 

제너릭컬렉션을 이용한 예제

 

l  TArray<T> 사용

Type

  TArrayEx = class(TArray)

    public

       class function CloneArray<T>(const A: array of T): TArray<T>;

  end;

 

{ TArrayEx} 

Implementation

class function TArrayEx.CloneArray<T>(const A: array of T): TArray<T>;

var

  Idx: Integer;

 

begin

  SetLength(Result, Length(A));

  

  for Idx := Low(A) to High(A) do

         Result[Idx - Low(A)] := A[Idx];

end;

 

procedure TForm1.Button1Click(Sender: TObject);

var

  IA: TArray<Integer>;

  SA: TArray<string>;

  FA:TArray<real>;

 

begin

  IA := TArrayEx.CloneArray<Integer>([0,1,2,3,5,6,7,8,9]);

  SA := TArrayEx.CloneArray<string>(['a', 'b','c']);

  FA := TArrayEx.CloneArray<real>([10.1,22.3]);

    ShowMessage(IntToStr(IA[3]));

end;

​​​​​​

 

l  TDictionary 사용

procedure TForm1.Button2Click(Sender: TObject);

begin

  var MyDictionary := TDictionary<string, Integer>.Create;

  MyDictionary.Add ('one', 1);

  MyDictionary.Add ('two', 2);

 

  var APair := MyDictionary.ExtractPair('two');

  Button2.Caption := APair.Value.ToString;

end;

 

 

l  TList<T> 사용

procedure TForm1.Button3Click(Sender: TObject);

var

  List: TList<Integer>;

  FoundIndex: Integer;

begin

   { Create a new List. }

   List := TList<Integer>.Create;

 

   { 몇 개의 데이터를 추가 }

   List.AddRange([5, 1, 8, 2, 9, 14, 4, 5, 1]);

 

   ShowMessage('첫번째1의 인덱스는 ' + IntToStr(List.IndexOf(1)));

   ShowMessage('마지막1의 인덱스는 ' + IntToStr(List.LastIndexOf(1)));

   ShowMessage('데이터에 100의 유무는? ' + BoolToStr(List.Contains(100)));

 

   {데이터 추가 }

   List.Add(100);

 

   ShowMessage(IntToStr(List.Count) + '개의 데이터가 있습니다.');

 

   { 첫번쨰 1 데이터 삭제 }

   List.Remove(1);

 

   { 첫번째 위치의 데이터 삭제 }

   List.Delete(0);

   List.DeleteRange(0, 2);

 

   { 리스트에서 남아있는 1을 지움 }

   List.Extract(1);

 

   {실제 길이 구함 }

   List.TrimExcess;

 

   ShowMessage('리스트 항목 갯수는 ' + IntToStr(List.Capacity));

 

   { 리스트 클리어 }

   List.Clear;

 

   { Insert some elements. }

   List.Insert(0, 2);

   List.Insert(1, 1);

   List.InsertRange(0, [6, 3, 8, 10, 11]);

 

  { 리스트 내용 소트 }

   List.Sort;

 

   { Binary search for the required element. }

   if List.BinarySearch(6, FoundIndex) then 

      ShowMessage('6 데이터의 인덱스는 ' + IntToStr(FoundIndex));

 

    { Reverse the list. }

   List.Reverse;

 

   ShowMessage('첫번째 데이터는 ' + IntToStr(List.Items[0]));

 

    List.Free;

end;

 

 

l  TObjectList<T: class> 사용 

type

  { Declare a new object type. }

 

  TNewObject = class

    private

      FName: String;

    public

     constructor Create(const AName: String);

     destructor Destroy; override;

end;

 

constructor TNewObject.Create(const AName: String);

begin

   FName := AName;

end;

 

destructor TNewObject.Destroy;

begin

  ShowMessage('오브젝트"' + FName + '" 해제되었습니다!');

  inherited;

end;

 

procedure TForm1.Button4Click(Sender: TObject);

{ TNewObject }

var

  List: TObjectList<TNewObject>;

  Obj: TNewObject;

begin

  { Create a new List. }

 

  { The OwnsObjects property is set by default to true -- the list will free the owned objects automatically. }

 

   List := TObjectList<TNewObject>.Create;

 

  { Add some items to the List. }

  

    List.Add(TNewObject.Create('One'));

    List.Add(TNewObject.Create('Two'));

 

  { Add a new item, but keep the reference. }

    Obj := TNewObject.Create('Three');

 

    List.Add(Obj);

 

  {

    Remove an instance of the TNewObject class. The destructor

    is called for the owned objects, because you have set the OwnsObjects

    to true

  }

 

   List.Delete(0);

 

  List.Extract(Obj);

 

  { Destroy the List completely -- more message boxes will be shown. }

 

  List.Free;

end.

 

* 제너릭 컬렉션을 사용한 예제 다음을 참고하세요!

 

위와 같이 제너릭을 사용해 보시니 기존의 소스 코드와 차이점을 느끼셨나요 ?  

제너릭 장점

제너릭 컬렉션()을 사용하면 여러분이 사용하고자 하는 데이터 타입을 담을 수 있는 특정 컨테이너()을 정의할 수 있습니다. 그러면 해당 데이터 타입에 부합하는 지를 컴파일러가 확인하므로 실행 중에 데이터 타입을 확인하지 않아도 됩니다. 그 결과, 코드가 더 깔끔하고 읽기도 더 쉽습니다. 애플리케이션은 더 견고해지고, 실행 시점에 확인할 필요가 줄어들기 때문에 실행 속도도 빨라집니다:

 

 

번호 제목 글쓴이 날짜 조회 수
공지 [DelphiCon 요약] 코드사이트 로깅 실전 활용 기법 (Real-world CodeSite Logging Techniques) 관리자 2021.01.19 14390
공지 [UX Summit 요약] 오른쪽 클릭은 옳다 (Right Click is Right) 관리자 2020.11.16 13023
공지 [10.4 시드니] What's NEW! 신기능 자세히 보기 관리자 2020.05.27 15532
공지 RAD스튜디오(델파이,C++빌더) - 고객 사례 목록 관리자 2018.10.23 21064
공지 [데브기어 컨설팅] 모바일 앱 & 업그레이드 마이그레이션 [1] 관리자 2017.02.06 22297
공지 [전체 목록] 이 달의 기술자료 & 기술레터 관리자 2017.02.06 17933
공지 RAD스튜디오(델파이, C++빌더) - 시작하기 [1] 관리자 2015.06.30 38228
공지 RAD스튜디오(델파이,C++빌더) - 모바일 앱 개발 사례 (2020년 11월 업데이트 됨) 험프리 2014.01.16 173741
230 [10.4] 커스텀 매니지드 레코드(Custom Managed Records) 험프리 2020.05.14 1108
229 델파이, 25년의 혁신 - 버전 1부터 10.3까지 버전별 핵심 기능 [2] 관리자 2020.05.12 2567
228 [10.4 시드니 신기능] 다시 태어난 '코드 인사이트' [2] file 험프리 2020.05.08 1661
227 [고객 사례- 의료, 델파이] COVID-19 - 검사 결과 실시간 확인 앱 관리자 2020.03.25 767
226 윈도우 10에서의 High DPI 김원경 2020.03.02 1248
225 델파이, C++빌더의 윈도우10과 High DPI 디스플레이 지원 김원경 2020.02.28 652
224 함께 축하해요! 델파이 25주년!! #Delphi25th file 관리자 2020.02.14 309
223 델파이 개발자를 위한 이더리움(Ethereum)! 관리자 2020.02.04 396
222 윈도우10에서 활용 가능한 델파이만의 5가지 기능들 관리자 2020.02.04 946
221 [코드레이지 2019] 웹소켓(WebSocket)과 델파이 험프리 2020.01.22 1200
» 제너릭(Generic)과 제너릭을 사용한 예제(제너릭 콜렉션 등) file 김원경 2020.01.15 1198
219 델파이 RTL: 새로운 제네릭 컬렉션 vs 기존 클래식 컬렉션 험프리 2020.01.06 769
218 [팁] 10.3.3 AAB에서 로컬서비스 실행시 문제점 해결 방법 험프리 2020.01.02 269
217 [고객사례-솔루션, 델파이] SQLGate - 데이터베이스 관리/개발 IDE 관리자 2019.12.19 470
216 델파이에서 아이콘 폰트 사용하기 험프리 2019.12.12 826
215 Class에서 Interface 두 개 구현할 때, 이 둘이 동일한 이름의 메소드(Method)를 가지고 있다면? file 험프리 2019.12.11 665
214 [고객사례-유틸리티, 델파이] 녹음기 앱 - Voice Recorder 관리자 2019.12.10 677
213 [10.3.3] 안드로이드 64비트 앱 빌드하기 [4] file 험프리 2019.11.27 1596
212 [델파이 샘플 코드] 안드로이드, iOS, OSX, 윈도우, 리눅스, HTML5 관리자 2019.11.13 670
211 [고객사례-게임, 델파이] Rise of Legions 관리자 2019.11.08 786