엠바카데로에서 FireDAC Skill Sprint 웨비나(1월 23일 ~ 3월 27일: 매주 금요일 10시)를 진행하고 있습니다.


이 글에서는 웨비나 다시보기와 함께 웨비나 일부 내용을 샘플코드와 함께 소개합니다. 하단 온라인 기술 도움말 링크를 통해 더 자세한 내용을 추가학습하시기 바랍니다.


4회차에는 Array DML에 대한 내용으로 진행합니다.

Array DML 이란?

Array DML은 실행에 필요한 매개변수(Parameters) 배열을 이용한 한번에 DBMS 명령을 실행하는 기능입니다. 이 방법은 DBMS와 애플리케이션 사이의 통신비용을 줄이고 DBMS 명령 요청을 줄입니다. 그 결과 실행 속도가 향상됩니다.


다음 그림에서 이 프로세스를 보여줍니다.


동영상을 보셨다면 아시겠지만 1만건의 데이터를 DBMS에 입력 시

  • 트랜젝션으로 작업을 묶어주면 20배 빨라지고, 

  • Array DML을 사용하면 다시 10배가 더 빨라진다고 설명합니다.

Array DML의 사용법 예시입니다.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
with FDQuery1 do begin
  SQL.Text := 'insert into Customers (ID, RegionID, Name, Note) values (:ID, :RegionID, :Name, :Note)';
  // Set up parameter types
  Params[0].DataType := ftInteger;
  Params[1].DataType := ftInteger;
  Params[2].DataType := ftString;
  Params[2].Size := 40;
  Params[3].DataSize := ftMemo;
  // Set up parameters' array size
  Params.ArraySize := 10000;
  // Set parameter values
  for i := 0 to 10000 - 1 do begin
    if i mod 100 = 0 then
      // force PK violation
      Params[0].AsIntegers[i] := i - 1
    else
      Params[0].AsIntegers[i] := i;
    Params[1].AsIntegers[i] := GetRegionIdForCustomer(i);
    Params[2].AsStrings[i] := 'Somebody ' + IntToStr(i);
    Params[3].Clear(i);
  end;
  // Execute batch
  Execute(10000, 0);
end;

  • 위 코드 10번째 줄에서 배열크기(Params.ArraySize)를 지정합니다.
  • 13~20번 줄에서는 Params[0].AsStrings[i] 형태로 배열로 데이터를 입력합니다.(AsString 뒤에 s가 붙은 것을 유의하세요.)
  • 데이터 입력 후 23번째 줄에 Execute 메소드로 실행요청을 합니다. 이때 배열의 크기를 인자로 넘겨줍니다.

Array DML 샘플 프로그램 소개

이 샘플에서는 만건의 데이터를 3가지 방식으로 입력하고 실행 시간을 출력합니다. 

  • 아무 튜닝없이 반복하며 입력 - 13,244 ms 소요
  • 트랜젝션으로 작업을 묶어서 입력 - 1,062 ms 소요
  • Array DML으로 데이터 일괄 입력 - 160 ms 소요
결과를 보면 Array DML의 결과가 매우 빠르다는 것을 볼수 있습니다. 
또한 단순하게 트랜젝션 처리만 추가해도 10배 이상 속도가 개선된 결과도 인상적입니다.

[샘플코드 받기 - 데브기어 github 페이지]


Insert STD - 아무 튜닝없이 반복하며 입력

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
var
  I: Integer;
  StopWatch: TStopwatch;
begin
  FDConnection1.ExecSQL('DELETE FROM Test');
 
  StopWatch := TStopWatch.StartNew;
 
  for I := 0 to NUM_INSERTS - 1 do
  begin
    FDQuery1.ParamByName('Field1').AsInteger := I;
    FDQUery1.ParamByName('Field2').AsString := 'Str' + I.ToString;
    FDQuery1.ExecSQL;
  end;
 
  StopWatch.Stop;
  Memo1.Lines.Add('Insert STD : ' + StopWatch.ElapsedMilliseconds.ToString + ' ms');

Insert STD(Transaction) - 위 작업에 트랜젝션만 추가
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
var
  I: Integer;
  StopWatch: TStopwatch;
begin
  FDConnection1.ExecSQL('DELETE FROM Test');
 
  StopWatch := TStopWatch.StartNew;
 
  // Transaction 추가
  FDConnection1.StartTransaction;
  try
    for I := 0 to NUM_INSERTS - 1 do
    begin
      FDQuery1.ParamByName('Field1').AsInteger := I;
      FDQUery1.ParamByName('Field2').AsString := 'Str' + I.ToString;
      FDQuery1.ExecSQL;
    end;
  finally
    FDConnection1.Commit;
  end;
 
  StopWatch.Stop;
  Memo1.Lines.Add('Insert STD(Transaction) : ' + StopWatch.ElapsedMilliseconds.ToString + ' ms');

Insert Array DML - Array DML을 이용해 입력
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
var
  I: Integer;
  StopWatch: TStopwatch;
begin
  FDConnection1.ExecSQL('DELETE FROM Test');
 
  StopWatch := TStopWatch.StartNew;
 
  FDConnection1.StartTransaction;
  try
    FDQuery1.Params.ArraySize := NUM_INSERTS;
    for I := 0 to NUM_INSERTS - 1 do
    begin
      FDQuery1.ParamByName('Field1').AsIntegers[I] := I;
      FDQUery1.ParamByName('Field2').AsStrings[I] := 'Str' + I.ToString;
    end;
    FDQuery1.Execute(NUM_INSERTS);
  finally
    FDConnection1.Commit;
  end;
 
  StopWatch.Stop;
  Memo1.Lines.Add('Insert ArrayDML : ' + StopWatch.ElapsedMilliseconds.ToString + ' ms');
번호 제목 글쓴이 날짜 조회 수
공지 [DelphiCon 요약] 코드사이트 로깅 실전 활용 기법 (Real-world CodeSite Logging Techniques) 관리자 2021.01.19 14387
공지 [UX Summit 요약] 오른쪽 클릭은 옳다 (Right Click is Right) 관리자 2020.11.16 13023
공지 [10.4 시드니] What's NEW! 신기능 자세히 보기 관리자 2020.05.27 15532
공지 RAD스튜디오(델파이,C++빌더) - 고객 사례 목록 관리자 2018.10.23 21064
공지 [데브기어 컨설팅] 모바일 앱 & 업그레이드 마이그레이션 [1] 관리자 2017.02.06 22297
공지 [전체 목록] 이 달의 기술자료 & 기술레터 관리자 2017.02.06 17933
공지 RAD스튜디오(델파이, C++빌더) - 시작하기 [1] 관리자 2015.06.30 38228
공지 RAD스튜디오(델파이,C++빌더) - 모바일 앱 개발 사례 (2020년 11월 업데이트 됨) 험프리 2014.01.16 173741
16 C++ 개발자를 위한 파이어닥(FireDAC) 시작하기 관리자 2020.01.14 304
15 [발표자료] What's NEW! RAD Studio 10.2 도쿄 험프리 2017.04.13 370
14 [코드레이지11] FireDAC 이해하기, RAD 스튜디오 데이터 엑세스 프레임워크 선택 - Cary Jensen 험프리 2016.11.24 533
13 [FireDAC Skill Sprints] 8. TFDMemTable: 메모리 기반 데이터셋 사용하기 Humphery 2015.04.06 2473
12 [FireDAC Skill Sprints] 9. LocalSQL: DB에서 가져온 데이터(데이터셋)를 대상으로 다시 SQL쿼리 실행하기 Humphery 2015.04.01 1888
11 [FireDAC Skill Sprints] 7. FireDAC ETL: 데이터 내보내기, 가져오기 기능 구현하기 Humphery 2015.04.01 2115
10 [FireDAC Skill Sprints] 1. FireDAC 소개 험프리 2015.04.01 1574
9 이 달의 기술자료 - 2015년 04월 험프리 2015.03.26 5669
8 [FireDAC Skill Sprints] 6. 전처리: SQL문을 유연하게 작성할 수 있는 Param와 Macro 사용하기 Humphery 2015.03.13 1675
7 [FireDAC Skill Sprints] 5. Cascading Options: 고급기능을 활용 할 수 있는 FireDAC 옵션 Humphery 2015.03.11 1304
» [FireDAC Skill Sprints] 4. ArrayDML로 30배 빠르게 데이터 입력하기 Humphery 2015.03.11 1484
5 [FireDAC Skill Sprints] 2. FireDAC으로 DBMS 사용 내역 추적, 모니터링 하기 Humphery 2015.03.07 1530
4 [FireDAC Skill Sprints] 3. 캐쉬를 이용한 업데이트와 자동증가필드(Identity) 적용 Humphery 2015.03.07 1490
3 이 달의 기술자료 - 2015년 03월 험프리 2015.02.25 15861
2 [온라인교육] FireDAC 무료 온라인 교육 안내 Humphery 2015.01.23 1052
1 FireDAC 시작하기 Humphery 2014.09.23 2959